import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
    `java-library`
    `maven-publish`
    id("com.github.hierynomus.license") version "0.16.1"
    id("io.github.goooler.shadow") version "8.1.7"
}

subprojects {
    apply(plugin = "java-library")
    apply(plugin = "maven-publish")
    apply(plugin = "com.github.hierynomus.license")
    apply(plugin = "io.github.goooler.shadow")

    group = "me.clip"
    version = "2.11.8-DEV-${System.getProperty("BUILD_NUMBER")}"

    description = "An awesome placeholder provider!"

    repositories {
        maven("https://oss.sonatype.org/content/repositories/snapshots/")

        mavenCentral()
        mavenLocal()

        maven("https://repo.codemc.org/repository/maven-public/")
        maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
        maven("https://repo.papermc.io/repository/maven-public/")
    }

    dependencies {
        implementation("org.bstats:bstats-bukkit:3.0.1")
        implementation("net.kyori:adventure-platform-bukkit:4.4.1")

        compileOnly("dev.folia:folia-api:1.21.11-R0.1-SNAPSHOT")
        compileOnlyApi("org.jetbrains:annotations:23.0.0")

        testImplementation("org.openjdk.jmh:jmh-core:1.32")
        testImplementation("org.openjdk.jmh:jmh-generator-annprocess:1.32")

        testImplementation("org.junit.jupiter:junit-jupiter-engine:5.8.2")
        testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.8.1")
    }


    java {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8

        withJavadocJar()
        withSourcesJar()

        disableAutoTargetJvm()
    }

    license {
        header = rootProject.file("config/headers/main.txt")

        include("**/*.java")
        mapping("java", "JAVADOC_STYLE")

        encoding = "UTF-8"

        ext {
            set("year", 2024)
        }
    }

    tasks {
        processResources {
            eachFile { expand("version" to project.version) }
        }

        build {
            dependsOn(named("shadowJar"))
        }

        withType<JavaCompile> {
            options.encoding = "UTF-8"
            options.release = 8
        }

        withType<Javadoc> {
            isFailOnError = false

            with(options as StandardJavadocDocletOptions) {
                addStringOption("Xdoclint:none", "-quiet")
                addStringOption("encoding", "UTF-8")
                addStringOption("charSet", "UTF-8")
            }
        }

        test {
            useJUnitPlatform()
        }
    }

    configurations {
        testImplementation {
            extendsFrom(compileOnly.get())
        }
    }

}